*top
c:c=n4
c:h2$="Chapter 4: "!!q$
*lesson
c:l2$="lesson"
c:j1$="lesson"
c:j2$=""
c:j0$=""
c:r9=4
c:r9$=str(r9)
c:r1$=e$!!"&a"!!r9$!!"R"
c:f7$="0"
c:h6$="List of Lessons"
c:n=4
t:$h1$ List of Lessons -- $h2$ $h4$ "
t:$d8$
~uDirections~n:__Highlight and start the desired lesson.

~uLessons~n:_____Viewing a Text File_$n$ _
	     ...(You'll highlight a file name and press ~i__View__~n.)

	     Positioning the Paper_$n$ _
	     ...(How to load paper, advance paper, and set top-of-form.)

             Copying the Display_$n$ _
	     ...(You'll use the [Shift][Print] keystroke.)

             Checking the Printer_$n$ _
             ...(Includes a printing self-test.)

             Printing a Text File_$n$ _
	     ...(You'll use the 'print' command.)

	     - - - - - - - - - - - - - - - $h$ 
q:
k:x
k:1 1 _Start_____f1
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
th:$r1$ $c1$
c:d9=0
*lloop
th(d9<c):$b$ $b$ $b$
c(d9<c):d9=d9+1
j(d9<c):lloop
th:$i$
as:
c:t1$=%B
c:m9=asc(t1$)
j(m9>127):mouse
j(t1$=t$):@p
j(t1$="C"):@p
j(t1$="B"):@p
j:leftup
pr:
c:c=c+1
th(c<=n):$c1$ $n$ $b$ $b$ $b$ $i$
th(c>n):$c1$ $n$ $r1$ $i$
c(c>n):c=0
j:@a
*leftup
j(t1$="i"):@p
j(t1$="D"):@p
j(t1$="A"):@p
j:soft
pr:
c:c=c-1
th(c>=0):$c1$ $n$ $a$ $a$ $a$ $i$
j(c>=0):@a
th:$c1$ $r1$ $n$
c:c=0
*loop
th:$b$ $b$ $b$
c: c=c+1
j(c<n):loop
th:$c1$ $i$
c:c=n
j:@a
*mouse
c:m9=m9-128
j(m9<=32):@p
s:
j:@a
pr:
c:i9=0
c:d9=r9
*yloop
j(i9=n + 1):fail
j(m9=d9):succss
c:d9=d9+s9
c:i9=i9+1
j:yloop
*fail
s:
j:@a
*succss
j(c=i9):@p
th:$c1$ $n$
c:a9$=str(d9)
th:~e&a$a9$ R$c1$ $i$
c:c=i9
j:@a
pr:
j:doit
*soft
j(t1$=c$):doit
mj:1
j:doit
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="j:"!!j1$
xi:j$
mj:7
c:j$="j:"!!j1$
j:helpL
mj:8
c:j$="j:"!!j1$
j:endall
xi:j$
m:anything
s:
j:@a
*doit
c(c=0):l1$="G"
c(c=1):l1$="A"
c(c=2):l1$="D"
c(c=3):l1$="E"
c(c=4):l1$="C"
c:j$="J:"!!L1$
xi:j$
*helpL
c:j1$="helpL"
t:$h1$ Tutor Help -- $h2$ $h4$ "
t:$d8$
~uHello~n!__________________You've just pressed ~i__Help__~n while looking
			at the list of lessons for this chapter.

~uDo You Need It~n?_________You need this chapter if you want to:

			- List out files on the display.
			- Print a copy of the screen.
			- Print files.

~uTo Select a Lesson~n:_____1.  Press ~iContinue~n (key [f1]).
			2.  Use the arrow keys or the mouse to ~ihighlight~n
			    and ~i_Start___~n the desired lesson.

~uTo Do Something Else~n:___1.  Press ~iContinue~n (key [f1]).
			2.  Press ~iChapters~n (key [f4]) to pick another
			    chapter.
		
th:$f1$ (Press ~iContinue~n to return to the list of lessons.) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*chap
c:n4=c
t:$h1$ Tutor Resting Place
t:$d8$
~uPlease wait~n:____________For the list of main chapters...

~uYou've Just Left~n:_______Chapter 4, "$h4$ ."

~uNext on the List~n:_______Chapter 5, "Protecting Your Information,"
			teaches:
			
			- How to care for flexible discs.
			
			- How to format new discs.
			
			- How to make extra copies of files and discs.
k:1 1 _
k:2 2 _
k:3 3 _
k:4 4 _
k:5 5 _
k:6 6 _
k:7 7 _
k:8 8 _
k:e
c:d$="Chapters/0:contents"
c:j$="begin"
c:x$="L:"!!d$!!","!!j$
xi:x$
*endall
c:j1$="endall"
t:$h1$ Tutor Exit Page
t:$d8$
~uThanks for Your Time~n!___To exit the tutor, press ~iYes,Quit~n (key [f8]).

~uTo Restart the Tutor~n:___1.  Highlight the name 'Tutor' in the PAM window.

			2.  Press ~i_Start__~n (key [f1]).

~uAfter Restarting~n:_______You can easily return to where you left off: 

			1.  When the tutor asks--"Is this your first
			    time?"--press [N] for "no."

			2.  When you see the list of chapters, highlight
			    and start this chapter:
			    "$h4$ ."

j(h6$<>"List of Lessons"):sless
th:$f1$ (Press ~iYes,Quit~n to leave, ~iContinue~n to select a lesson.) $h$
j:@p
*sless
t:			3.  After the chapter is loaded in memory,
			    highlight and start this lesson:
			    "$h6$

th:$f1$ (Press ~iYes,Quit~n to leave, ~iContinue~n to continue on page #p .) $h$
pr:
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 Yes,Quit___f8
k:e
as:
mj:1
c:d9=FLO(f7$)
j(p=1):ret
j(p=d9):ret
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
*ret
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:@p
m:anything
s:
j:@a
pr:
t:$h1$ Done
t:$d8$
			Good-bye from tutor... 
e:
*A
c:f7$="9"
*A1
c:j0$=""
c:j1$="A1"
c:h5$=q$!!"  "
c:h6$="Positioning the Paper"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll be able to feed paper in the built-in
			printer and set the top-of-form.

~uBegin~n:__________________The setup guide shows how to load printer
			paper.

			Do you want a review of loading printer paper?

			- If yes, press ~i_Review_~n (key [f3]).

			- If no, press ~iNoReview~n (key [f4]).  (If you
			  choose this option, you'll skip right to the
			  instructions on positioning the paper.)

th:$f1$ (Press ~i_Review_~n or ~iNoReview~n.)
th:____________________________$f3$ #p  of $f7$ $f5$ 
q:
k:x
k:3 3 _Review____f3
k:4 4 NoReview___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:3
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+1
c:a9=1
c:j2$="A2"
c:j$="J:"!!j2$
xi:j$
mj:4
k:1 1 NextPage___f1
k:2 2 PrevPage___f3
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+3
c:a9=0
c:j2$="A5"
c:j$="J:"!!j2$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:J$
mj:7
c:j$="J:"!!j1$
j:help1
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*keyA
k:x
k:1 1 NextPage___f1
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:1
k:2 2 PrevPage___f2
k:e
c:p=p+1
c:j$="J:"!!j2$
xi:j$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:j$
mj:7
c:j$="J:"!!j1$
j:help1
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@A
*help1
c:j1$="help1"
t:$h1$ Tutor Help -- Lesson "$h6$
t:$d8$
~uHello~n!__________________The lessons in Chapter 4,
			"$h4$ ," teach how to:

			- Use ~i__View__~n (key [f1] of PAM) to view 
			  text files.

			- Use the [LF] and [FF] printer buttons to
			  advance paper in the built-in printer.

			- Use the light grey printer button to set the
			  top-of-form.

			- Use the [Shift][Print] keystroke to make
			  screen copies.

			- Use the 'print' command to print text files.
			
th:$f1$ (Press ~iContinue~n to return to page #p .) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*A2
c:j0$="A1"
c:j1$="A2"
c:j2$="A3"
xi:x1$
t:$h8$
t:$d8$
~uLoading Printer Paper~n:

~uSteps~n:__________________1.  Open the front cover and the bail arm of
			    the built-in printer.

			2.  Slide the paper into the slot at the back of
			    the printer.

			(You want the ~usmooth~n side of the paper to
			come out ~ufacing you~n as you slide the paper
			through the slot.
			
			That is, the print head should apply ink to
			the ~usmooth~n side.)

t:$f8$
q:
*keyB
as:
mj:1
c:p=p+1
c:j$="J:"!!j2$
xi:j$
mj:2
c:p=p-1
c:j$="J:"!!j0$
xi:J$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:J$
mj:7
c:j$="J:"!!j1$
j:help2
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*help2
c:j1$="help2"
t:$h1$ Tutor Help -- Lesson "$h6$
t:$d8$
~uHello~n:__________________Welcome to the help for page #p .

			You're reading chapter 4:
			"$h4$ ."

			The point is for you to learn printer
			operations.  You should learn how to:

			- Display and print the contents of text files.

			- Position printer paper correctly.

			- Make printed copies of the screen.

			Refer to the setup guide for installation
			information; refer to the owner's manual for
			troubleshooting and maintenance information.

th:$f1$  (Press ~iContinue~n to return to page #p .) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*keyZ
k:x
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:2
k:1 1 NextPage___f1
k:e
c:p=p-1
c:j$="J:"!!j0$
xi:j$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:j$
mj:7
c:j$="J:"!!j1$
j:help3
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*help3
c:j1$="help3"
t:$h1$ Tutor Help -- Lesson "$h6$ 
t:$d8$
~uHello~n:__________________You've been reading the last page--page $f7$ --of
			this lesson.

			At this point, you can:

			- Go on to the ~unext~n lesson:
			  1.  Press ~iContinue~n (key [f1]). 
			  2.  Press ~iLessons_~n (key [f3]) to return
			      to the list of lessons.

			- Review the material in ~uthis~n lesson:
			  1.  Press ~iContinue~n (key [f1]).
			  2.  Press ~iPrevPage~n (key [f2]) to review
			      previous pages.

			- Quit the tutor altogether:
			      Press ~i__Quit__~n (key [f8]) ~utwice~n.

th:$f1$ (Press ~iContinue~n to return to page #p .) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*A3
c:j1$="A3"
c:j2$="A5"
c:j0$="A2"
xi:x1$
t:$h8$
t:$d8$
~uReview of Loading Printer Paper~n: (cont.)

			3.  Pull the top edge of the paper so that
			    it is above the bail arm rollers.

			4.  Align the holes in the sides of the paper
			    with the printer pin wheels.  (The ~uright~n
			    pin wheel slides for adjusting the width.)

			5.  Close the bail arm and the printer cover.

			OK!  Done with the loading.  Now for the
			positioning...

th:$f8$
q:
j:keyB
*A5
c:j1$="A5"
c:j2$="A6"
xi:x1$
t:$h8$
t:$d8$
~uPositioning the Paper~n:__Make sure that the top (or perforated) edge of
			the paper is positioned just above the pinch rollers.

			To advance paper in the printer:

			    Press and hold down the [LF] (~uline feed~n)
			    button.

			The [LF] button is located on the top side of
			the computer, near the paper slot.

			    +-----------+
			    | *    **** |
			    | *    *    |
			    | *    **** |
			    | *    *    |
			    | **** *    |
			    +-----------+

th:$f8$
q:
c(a9=0):j0$="A1"
c(a9=1):j0$="A3"
j:keyB
*A6
c:j1$="A6"
c:j2$="A6A"
c:j0$="A5"
xi:x1$
t:$h8$
t:$d8$
~uSetting Top-of-Form~n:____You should set the ~utop-of-form~n (where
			the first line is printed on a new page) when
			the page perforation is just above the pinch
			roller.

			Setting the top-of-form is easy:

			1.  Align the paper relative to the print head.

			2.  Press the light grey, touch-membrane button.
			    ~u______~n
			    ~i_~n____~i_~n
			    ~i______~n
			    ~i______~n
			    ~i~_~_~_~_~_~_~n

~uNote~n:___________________The top-of-form is also set when you switch on
			the computer.

th:$f8$
q:
j:keyB
*A6A
c:j1$="A6A"
c:j0$="A6"
c:j2$="A7"
xi:x1$
t:$h8$
t:$d8$
~uPrinter Settings~n:_______The following are normal printer settings:
                        +---+------------------+---+
                       /|   |                  |   |
                      / |   |                  | <---- 1" left and right
                     /  |   |                  |   |   margins
                    /   |   |<--80 characters->|   |
                   /    |   |   per line      /|   |
                  /     |   |                / |   |  
                 /      |   |         6 lines  |   |
               66 lines |   |         per inch |   |
               per page |   |                \ |   |
                 \      |   |                 \|   |
                  \     |   |                  |   |
                   \    |   | Hello there!     |   |
                    \   |   | \          /     |   |
                     \  |   | 12 characters    |   |
                      \ |   | per inch         |   |
                       \|   |                  |   |
                        +---+------------------+---+
th:$f8$
q:
j:keyB
*A7
c:j1$="A7"
c:j2$="A8"
c:j0$="A6A"
xi:x1$
t:$h8$
t:$d8$
~uPaper Supply~n:___________Put the paper supply any distance behind the
			printer.  

			Make sure that the paper feeds easily (with a
			minimum of resistance) into the printer.

~uTransporting the Unit~n:__If you want to move the computer a short
			distance, move the paper supply with the unit.

~uA Long Way~n:_____________Before moving the computer a long way,
			remove the paper supply (the next page tells
			how) and shut the computer into its case.

			You don't need to remove the print head, ~uunless~n
			you'll be laying the computer on its side.  If
			you intend to stow the computer under an airline
			seat, for example, you ~ushould~n remove the
			print head to avoid ink seepage.

th:$f8$
q:
j:keyB
*A8
c:j1$="A8"
c:j2$="A9"
c:j0$="A7"
xi:x1$
t:$h8$
t:$d8$
~uRemoving Paper~n:_________It's easiest to remove paper while the computer
			is still switched on.

			To remove paper:

			1.  Tear off the paper from behind, at the
			    sheet that enters the printer.

			2.  Press the [FF] to cause a form-feed.

			The remaining sheet will feed out of the printer.

			Also note:  It's easiest to close the computer
			with the paper ~uremoved~n.

th:$f8$
q:
j:keyB
*A9
c:j1$="A9"
c:j2$=""
c:j0$="A8"
xi:x1$
t:$h8$
t:$d8$
~uSummary~n:________________To prepare the built-in printer:

			1.  Load printer paper from the rear of the
			    printer.

			2.  Use the [LF] button and the light grey button to
			    set the top-of-form.

			Remove paper when transporting the computer over
			long distances.

~uNext~n:___________________The next lesson, "Copying the Display," shows
			how to duplicate the display on printer paper
			--easily.

th:$g6$ #p  of $f7$ $f5$
q:
j:keyZ
*G
c:f7$="6"
*G1
c:j0$=""
c:j1$="G1"
c:j2$="G2"
c:h5$=q$!!"   " 
c:h6$="Viewing a Text File"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll know how to display the contents of a
			text file.

~uBegin~n:__________________A ~utext file~n is a file that has simple text
			characters (such as 'ABC') in it.  Text files
			are usually created by text ~ueditors~n, such as
			MemoMaker.

~uWhat's Inside~n?__________Frequently, you may want to ~uview~n what's inside
			a text file without actually editing or printing
			that file.

			The ~i__View__~n key makes this possible.  Pressing
			~i__View__~n causes the computer to create a
			read-only window and display your text file, one
			page at a time.

t:$f8$
q:
j:keyA
*G2
c:j0$="G1"
c:j1$="G2"
c:j2$="G3"
xi:x1$
t:$h8$
t:$d8$
~uLet's View a File~n!______Included on the tutor disc is a text file
			named 'excerpt'.  

~uRead Before Doing~n:______To view the 'excerpt' text file:

			1.  Select the PAM window (not yet).

			2.  Use the arrow keys or the mouse to highlight
			    the name 'excerpt'.  (Note that key label
			    [f1] changes to ~i__View__~n.)

			3.  Press ~i__View__~n (key [f1]) --OR--

			    Press the mouse button a second time.

			4.  Select this tutor window and read on.

			Ready...set...go!

th:$f1$ $k$ (Press ~iNextPage~n after creating a window with ~i__View__~n.)
:___$f3$ #p  of $f7$ $f5$
q:
j:keyB
*G3
c:j0$="G2"
c:j1$="G3"
c:j2$="G4"
xi:x1$
t:$h8$
t:$d8$
~uThree Windows at Once~n:__If things went as planned, you now have three
			windows:
			
			(a) This tutor window, labeled ~i_Tutor______~n.

			(b) The PAM window, labeled ~i_PAM_________~n.

			(c) The new view window, labeled ~i_excerpt_____~n.

~uYour Options Now~n:_______With a view window, you can either:

			- Read through the view file:  Press ~i__More__~n
			  (key [f1])
			      --OR--
			- Stop reading:  Press ~i__Quit__~n (key [f8]).

~uOn the Next Page~n:_______You'll try using the ~i__More__~n and ~i__Quit__~n
			keys.

t:$f8$
q:
j:keyB
*G4
c:j0$="G3"
c:j1$="G4"
c:j2$="G5"
xi:x1$
t:$h8$
t:$d8$
~uLet's View All of It~n:___The ~i__More__~n key lets you read through a text
			file.

~uRead Before Doing~n:______To page through the 'excerpt' file:

			1.  Select the view window (not yet).

			2.  Press ~i__More__~n (key [f1]) until you
			    reach the end of the file.  (Note that the
			    ~i__More__~n label will disappear at the last
			    page of text.)

			3.  Press ~i__Quit__~n (key [f8]) to eliminate the
			    view window.

			4.  Select this tutor window and read on.

			Do it now!

t:$f8$
q:
j:keyB
*G5
c:j0$="G4"
c:j1$="G5"
c:j2$="G6"
xi:x1$
t:$h8$
t:$d8$
~uWhat You've Done~n:_______You've just highlighted a text file and
			viewed all of it.  Good!

~uA Final Exercise~n:_______To check your understanding, do the
			following:

			1.  Once again, view the 'excerpt' file.

			2.  Quit after the first page.

			Try it!

th:$f8$
q:
j:keyB
*G6
c:j1$="G6"
c:j2$=""
c:j0$="G5"
xi:x1$
t:$h8$
t:$d8$
~uSummary~n:________________This lesson has shown that:

			- One of the things you can do with text files
			  is to ~uview~n them.

			- To view a text file, highlight the file name
			  and press ~i__View__~n (keyboard) or press
			  the select button (mouse).

~uNext~n:___________________The next lesson, "Positioning the Paper,"
			shows how to prepare the built-in printer for
			printing.

			Refer to ~uConnecting Peripherals to the Integral PC~n
			for information about using ~uexternal~n printers.

th:$g6$ #p  of $f7$ $f5$
q:
j:keyZ
*C
c:f7$="10"
*C1
c:j0$=""
c:j1$="C1"
c:j2$="C2"
c:h5$=q$!!"  "
c:h6$="Printing a Text File"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll be able to use the 'print' command
			to print a text file.

~uBegin~n:__________________~uPrinting a file~n simply means sending the
			characters in that file to the printer where
			they are printed.

~uIt's Simple~n:____________Printing a file involves two steps:

			1.  Selecting the PAM window with
			    [Shift][Select] or with the mouse.

			2.  Entering the 'print' command in the PAM
			    ~ucommand line~n.  (The command line is
			    where you type to control the whole system.)
			
			In an earlier lesson, you ~uviewed~n the 'excerpt'
			file.  In this lesson, you'll ~uprint~n it.

th:$f8$
q:
j:keyA
*C2
c:j1$="C2"
c:j2$="C2A"
c:j0$="C1"
c:a9=0
c:a9$=""
c:a9$=""
xi:x1$
t:$h8$
t:$d8$
~uPrerequisite 1~n._________Your printer should be ready to print.  If
			it's not, refer to:
			
			- The lesson "Positioning the Paper" earlier in
			  this chapter,

			      --OR--

			- The setup guide for printer installation.

~uPrerequisite 2~n._________You need to be able to see the name 'excerpt'
			in the PAM list of ~uData Files~n.  (Check now.)

~uPrerequisite 3~n._________You need to learn how to ~utype~n in the PAM
			~ucommand line~n.
			
			Typing in the command line is easy!

th:$f1$ $k$ (Press ~iNextPage~n for typing practice.)
:____________________$f3$ #p  of $f7$ $f5$
q:
j:keyB
*C2A
c:j1$="C2A"
c:j0$="C2"
c:j2$="C3"
xi:x1$
c:s1$=chr(7)
th:~e&f1k1a1d1L $s1$ ~e&f2k1a1d1L $s1$ ~e&f3k1a1d1L $s1$ ~e&f4k1a1d1L $s1$ 
th:~e&f5k1a1d1L $s1$ ~e&f6k1a1d1L $s1$ ~e&f7k1a1d1L $s1$ ~e&f8k1a1d1L $s1$
th:~e&a0C
k:e
*C2B
c:j1$="C2B"
t:$h8$
t:$d8$
~uHere, Let's Practice~n:___Below is a sample area for you to practice the
			'print' command.

			Type the following in this tutor window:

			    print excerpt

			Then press [Return].

~uType Here~n: --> --> --> --> $a9$  __

j(a9=1):@p
th:$f1$ (Type the 'print' command and press [Return].)
th:_________$f3$ #p  of $f7$  -- ~e&a28c11R
q:
s:
a:$a9$
c:t9=len(a9$)
c:a9=1
pr:
j(t9<50):@p
c:a9$=a9$(1,50)
t:
~uWait a Minute~n!__________You typed 'way too many letters.

			The correct spelling is 'print excerpt'.

			Press ~iPrevPage~n if you'd like to try again.

th:$f1$ (Press ~iPrevPage~n for more practice.)
:__________________$f3$ #p  of $f7$ $f5$
q:
j:showk
pr:
j(a9$<>"print excerpt"):@p
t:
~uGreat~n!__________________You typed '$a9$ '.

			That's exactly the way it should be.  Press
			~iNextPage~n to try out the real thing.

th:$f8$
q:
j:showk
pr:
j(a9$<>""):@p
t:
~uNothing~n?________________You choose not to try?

			- To review, press ~iPrevPage~n.
			
			- To go on, press ~iNextPage~n.

th:$f1$ (Press ~iPrevPage~n or ~iNextPage~n.)
:_____________________$f3$ #p  of $f7$ $f5$
q:
j:showk
pr:
t:
~uOh, Oh~n..._______________You spelled '$a9$ '.
			The correct spelling is 'print excerpt'.

			Press ~iPrevPage~n to try again.

th:$f1$ (Press ~iPrevPage~n for more practice.)
:__________________$f3$ #p  of $f7$ $f5$
q:
*showk
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
j:keyB
*C3
c:j1$="C3"
c:j2$="C4"
c:j0$="C2A"
xi:x1$
t:$h8$
t:$d8$
~uRead Before Doing~n:______To print the 'excerpt' file:

			1.  Select the PAM window (not yet).

			2.  Type this in the PAM command line:

			       print excerpt

			    (Please watch your spelling.  Note that only
			    ~ulowercase~n letters are used.)

			    Use [Back space] to correct any mistakes.

			3.  Press the [Return] key to start printing.

			4.  Select this tutor window again and read on.

			Ready?  Do it!

th:$f1$ $k$ (Press ~iNextPage~n after starting the printer.)_______
:_______$f3$ #p  of $f7$ $f5$
q:
j:keyB
*C4
c:j1$="c4"
c:j2$="c4A"
c:j0$="C3"
xi:x1$
t:$h8$
t:$d8$
~uDid It Work~n?____________The printer should be printing a pageful
			of prose.  If it isn't:

			- Check your spelling:  'excerpt' is spelled
			  'excerpt'.

			- Check that the name 'excerpt' appears in the
			  PAM window.

~uTo Try It Again~n:________Press ~iPrevPage~n (key [f2]) of the tutor to
			reread the print instructions.

~uRemember~n:_______________To print a file, type:

			    print ~ufile_name~n [Return],

			where ~ufile_name~n means your text file.

th:$f8$
q:
j:keyB
*C4A
c:j1$="C4A"
c:j0$="C4"
c:j2$="C4B"
xi:x1$
t:$h8$
t:$d8$
~uContinuing On~n...________Note that you don't have to wait for the printer
			to finish printing before you go on to something
			else:

			    Printing a file...
			|--------------------------->|

			           Reading from the tutor...
			       |------------------------------------>

			The printer will finish on its own.

th:$f8$
q:
j:keyB
*C4B
c:j1$="C4B"
c:j0$="C4A"
c:j2$="C5"
xi:x1$
t:$h8$
t:$d8$
~uHow Do You Stop It~n?_____In case you want to cancel a print operation,
		   	use the 'stopprint' command.

~uGot That~n?_______________To stop the printer:

			1.  Select the PAM window.

			2.  Type in the command line:

		    	   stopprint [Return].

			Note that 'stopprint' is all ~ulowercase letters~n,
			has two "p"'s, and is ~uone word~n.

			Note also that the printer can hold up to 1,024
			characters ~uat a time~n, so that a 'stopprint'
			command won't take effect immediately.

th:$f8$
q:
j:keyB
*C5
c:j1$="C5"
c:j2$="C6"
c:j0$="C4B"
xi:x1$
t:$h8$
t:$d8$
~uOne Other Thing~n:________You can specify more than one file name in
			the 'print' command.   For example, typing:

			    print memo1 memo2 memo3 [Return].

			causes the three memos to be printed, one after
			another.

~uWhat's The Difference~n?__Why, you may be asking, does PAM show 'excerpt'
			as a ~uData~n file rather than a ~uText~n file?

			The answer is that all text files (such as memos)
			are data files, but not all data files (such as
			spreadsheets) are text files.  PAM lists both
			types of files simply as ~uData Files~n.

th:$f8$
q:
j:keyB
*C6
c:j1$="C6"
c:j2$="C9"
c:j0$="C5"
xi:x1$
t:$h8$
t:$d8$
~uUse Common Sense~n:_______It makes good sense to print ~utext~n files.  It
			may not make such good sense to use the 'print'
			command on other ~udata~n files, or on ~uprograms~n,
			or on ~ufolders~n. 

			            +-----------+
			            | %6&**<    | ------+  "Forget it!"
			            |   ????    |        \  
			            |       ()( |         \
			            |   !!!$%^& |          v
			            |           |    +-------------+
			            +-----------+     \WASTEBASKET/
			                               \         / 
			                                \       /  
			                                 +-----+

			If you try, no harm will occur to the computer,
			but the printer will undoubtedly print garbage.

th:$f8$
q:
j:keyB
*C9
c:j1$="C9"
c:j2$=""
c:j0$="C6"
xi:x1$
t:$h8$
t:$d8$
~uThat's All~n._____________You've learned how to print text files on the
			built-in printer.   Nice going.

~uSummary~n:________________To print a file, type in the PAM command line:

		           print ~ufile_name~n [Return],

		        where ~ufile_name~n is the name as it appears in
			the PAM list of data files.

			To cancel a print operation, type:

			   stopprint [Return].

~uYou've Finished This~n____To read over the other chapters in the tutor,
~uChapter~n:________________~iChapters~n (key [f4]).

th:$f1$ $k$ (Press ~iChapters~n to pick from the list of chapters.)
:_______$f3$ #p  of $f7$ $f5$
q:
j:keyZ
*D
c:f7$="3"
*D1
c:j0$=""
c:j1$="D1"
c:j2$="D2"
c:h5$="    "
c:h6$="Copying the Display"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll know to use [Shift][Print] to print
			the entire display.

~uThere When You Need It~n:_Occasionally, you may want to print the
			entire contents of the EL display:

			    Use the [Shift][Print] keystroke.

~uJust a Second~n!__________Before beginning, make sure that:

			- Your printer is ready to print.
			                     +--------+
			- You know where the | Print  | key is.
			                     | Enter  |
			                     +--------+
			(Look at lower left corner of the keyboard.)

th:$f8$
q:
j:keyA
*D2
c:j1$="D2"
c:j0$="D1"
c:j2$="D3"
xi:x1$
t:$h8$
t:$d8$
~uTry It Now~n:_____________While holding down the [Shift] key, press the
			[Print] key.

~uIf It Works~n:____________You'll be watching your printer make a
			dot-for-dot copy of the display image.

~uA Little Sign~n:__________The computer presents a little ~i_print~_screen_~n
			banner to show the goings on. When the operation
			is over, the banner changes to ~i(print~_screen)~n.

~uIf There's Trouble~n:_____The yellow attention light next to the
			printer will blink.  To restore order:

			1.  Check the paper supply.

			2.  Press the light grey button by the attention
			    light.  The light should turn off.

th:$f1$ $k$ (Press ~iNextPage~n after pressing [Shift][Print].)_______
:__$f3$ #p  of $f7$ $f5$
q:
j:keyB
*D3
c:j1$="D3"
c:j2$=""
c:j0$="D2"
xi:x1$
t:$h8$
t:$d8$
~uAfterwards~n:_____________You can advance the paper in the printer:

			- Press the [LF] printer button several times
			  for line feeds,

			      --OR--

			- Press the [FF] printer button ~uonce~n
			  for a form feed.

~uSummary~n:________________To print the display on the printer, press
			[Shift][Print].

~uNext~n:___________________The next lesson, "Checking the Printer,"
			enables you to put the printer through a 
			complete printing self-test.

th:$g6$ #p  of $f7$ $f5$
q:
j:keyZ
*E
c:f7$="7"
*E1
c:j0$=""
c:a9=0
c:j1$="E1"
c:j2$="E2"
c:h5$=q$!!"  "
c:h6$="Checking the Printer"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll be able to verify the proper operation
			of the printer using a printing self-test.

~uNormal Operation~n:_______At power on, with paper in the printer:

			1.  The yellow attention light next to the
			     printer blinks during a "wake up"
			     self-test.

			2.  The print head clicks back and forth.

			3.  The attention light turns off (after about 2
			    seconds).
			               O O O   K   K    !
			              O     O  K  K     !
			              O     O  K K      ! 
			              O     O  K   K    !
			               O O O   K    K   o

th:$f8$
q:
j:keyA
*E2
c:j1$="E2"
c:j2$="E3"
c:j0$="E1"
xi:x1$
t:$h8$
t:$d8$
~uSomething May Be Wrong~n:_If the yellow attention light continues to
			blink.  The attention light should not be
			visible during normal printer operations.

			                    \ /
			                  -- o --
			                    / \

~uMaybe You're Out Of~n_____If the printer stops printing and the yellow
~uPaper~n:_________________ attention light begins to shine steadily,
			the printer is out of paper.  Keep reading!

th:$f8$
q:
j:keyB
*E3
c:j1$="E3"
c:j2$="E4"
c:j0$="E2"
xi:x1$
t:$h8$
t:$d8$
~uTo Fix a Problem~n:_______Check the paper supply:

			- If there is a misfeed or crumpled sheet, clear
			  it by freeing and realigning the paper.

			- If the printer is out of paper, replace the
			  paper supply.

~uAfterwards~n:_____________Press the light grey button, which should turn
			off the attention light and prepare the printer
			to print.

			The top-of-form will be set to the current line
			position, and the print head will be returned to
			the leftmost carriage position.

:<--- <--- <--- <--- <--- <--- <--- <--- <--- 
:(Over here.)

th:$f8$
q:
j:keyB
*E4
c:j1$="e4"
c:j0$="E3"
c:p=4
xi:x1$
t:$h8$
t:$d8$
~uPrinting Self-Test~n:_____Right now, you can cause the printer to
			perform a complete printing self-test.
			
			You'll get a page of paper with rows and rows
			of characters as part of the test.

~uBefore Starting It~n:_____See that the top-of-form is set so that the
			page perforation is slightly above the print
			head. (If necessary, realign the paper and press
			the light grey button.)

			Do you want the printer to perform a printing
			self-test?

			- If yes, press ~iPrntTest~n (key [f3]).

			- If no, press ~iSkipTest~n (key [f4]).

th:$f1$ (Press ~iPrntTest~n or ~iSkipTest~n as you desire.)
th:_____________$f3$ #p  of $f7$ $f5$ 
q:
k:1 1 _
k:3 3 PrntTest___f3
k:4 4 SkipTest___f4
k:e
as:
mj:3
k:1 1 NextPage___f1
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+1
c:j2$="X1"
c:j$="J:"!!j2$
xi:j$
mj:4
k:1 1 NextPage___f1
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+3
c:a9=1
c:j2$="E7"
c:j$="J:"!!j2$
xi:j$
mj:2
k:1 1 NextPage___f1
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p-1
c:j$="J:"!!j0$
xi:J$
mj:5
q:print
c:j$="J:"!!j1$
xi:J$
mj:7
c:j$="J:"!!j1$
j:help2
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*X1
c:j1$="X1"
c:j0$="E4"
c:j2$="E6"
xi:x1$
t:$h8$
t:$d8$
~uOK~n:_____________________Begin test...

			(Note that this test is built to run only once
			per lesson, but you can restart this lesson 
			to run the test again.)

			The printer will print a page of text and then
			advance the paper to the next top-of-form.

~uNo Need To Wait~n:________Go ahead and press the ~iNextPage~n
			key--there's no need to wait for the printer to
			finish.


th:$f8$
j(a9=1):@p
c:a9=1
q:print
th:$e$ z
pr:
q:
j:keyB
*e6
c:j1$="E6"
c:j2$="E7"
c:j0$="X1"
xi:x1$
t:$h8$
t:$d8$
~uYour Printer Prints~n_____If you're ending up with a sheet of paper
~u150 Characters/Second~n:__covered with lines of sharply defined
			characters, then the printer is passing its
			printing self-test.

			    Your printer works the way it's supposed to.

~uTry Again~n?______________To run the printer test again (only if you want):

			1.  Press the ~iPrevPage~n key until you get back
			    to page 1 of this lesson, "$h6$ .

			2.  Read through the lesson and press ~iPrntTest~n
			    again.

			If the print quality is not as good as you'd
			expect, please refer to Appendix G of the
			owner's manual for printer care information.

th:$f1$ $k$ (Press ~iNextPage~n to read the last page of this lesson.)
:___$f3$ #p  of $f7$ $f5$
q:
j:keyB
*e7
c:j1$="e7"
c:j2$=""
xi:x1$
t:$h8$
t:$d8$
~uSummary~n:________________This lesson contains a printing self-test
			that you can use to verify the proper operation
			of the printer.

~uRemember~n:_______________After loading or readjusting paper, press the 
			light grey printer button to set top-of-form.

~uNext~n:___________________The last lesson in this Chapter, "Printing a
			Text File," shows how to print your memos and
			other documents using the PAM window.

th:$g6$ #p  of $f7$ $f5$
q:
c(a9=0):j0$="E4"
c(a9=1):j0$="E6"
j:keyZ
*SYSX
th:$h1$
t:
:Welcome to PILOT!  Type a command and press [Return]:
c:z8=1
J:BEGIN9
*SYYY
TH:calc mode ([Return] to exit):_
AX:$Z9$
J(Z9$=""):BEGIN9
M:=
CN:Z9$="Z9="!!Z9$
C:Z9$="C:"!!Z9$
XI:Z9$
TE: ..no good
JE: @A
TN: Answer is #Z9 .
J:SYYY
*BEGIN9
TH:#z8 )_
AX:$Z9$
c(z9$<>""):z8=z8+1
M:bye
JY:calret
M:calc
JY:SYYY
XI:Z9$
TE:...oh, well
J:BEGIN9
*calret
c:x$="e:"!!j1$
xi:x$