*top
c:c=n2
c:h2$="Chapter 2: "!!q$
*lesson
c:l2$="lesson"
c:j1$="lesson"
c:j2$=""
c:j0$=""
c:r9=4
c:r9$=str(r9)
c:r1$=e$!!"&a"!!r9$!!"R"
c:f7$="0"
c:h6$="List of Lessons"
c:n=3
t:$h1$ List of Lessons -- $h2$ $h4$ "
t:$d8$
~uDirections~n:__Highlight and start the desired lesson.

~uLessons~n:_____Starting a Program_$n$ _
             ...(You'll insert a disc, pick a program, and go.)

	     Inverting Window Colors_$n$ _
	     ...(You have a choice--black on amber, or ~uvice versa~n.)

             Stopping a Program_$n$ _
	     ...(Use the [Stop] key or a function key.)

             Updating PAM_$n$ _
	     ...(To reread your disc and update the display.)

	     - - - - - - - - - - - - - - - $h$ 
q:
k:x
k:1 1 _Start_____f1
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
th:$r1$ $c1$
c:d9=0
*lloop
th(d9<c):$b$ $b$ $b$
c(d9<c):d9=d9+1
j(d9<c):lloop
th:$i$
as:
c:t1$=%B
c:m9=asc(t1$)
j(m9>127):mouse
j(t1$=t$):@p
j(t1$="C"):@p
j(t1$="B"):@p
j:leftup
pr:
c:c=c+1
th(c<=n):$c1$ $n$ $b$ $b$ $b$ $i$
th(c>n):$c1$ $n$ $r1$ $i$
c(c>n):c=0
j:@a
*leftup
j(t1$="i"):@p
j(t1$="D"):@p
j(t1$="A"):@p
j:soft
pr:
c:c=c-1
th(c>=0):$c1$ $n$ $a$ $a$ $a$ $i$
j(c>=0):@a
th:$c1$ $r1$ $n$
c:c=0
*loop
th:$b$ $b$ $b$
c:c=c+1
j(c<n):loop
th:$c1$ $i$
c:c=n
j:@a
*mouse
c:m9=m9-128
j(m9<=32):@p
s:
j:@a
pr:
c:i9=0
c:d9=r9
*yloop
j(i9=n + 1):fail
j(m9=d9):succss
c:d9=d9+s9
c:i9=i9+1
j:yloop
*fail
s:
j:@a
*succss
j(c=i9):@p
th:$c1$ $n$
c:a9$=str(d9)
th:~e&a$a9$ R$c1$ $i$
c:c=i9
j:@a
pr:
j:doit
*soft
j(t1$=c$):doit
mj:1
j:doit
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="j:"!!j1$
xi:j$
mj:7
c:j$="j:"!!j1$
j:helpL
mj:8
c:j$="j:"!!j1$
j:endall
xi:j$
m:anything
s:
j:@a
*doit
c(c=0):l1$="A"
c(c=1):l1$="D"
c(c=2):l1$="B"
c(c=3):l1$="E"
c:j$="J:"!!L1$
xi:j$
*helpL
c:j1$="helpL"
t:$h1$ Tutor Help -- $h2$ $h4$ "
t:$d8$
~uHello~n!__________________You've just pressed ~i__Help__~n while looking
			at the list of lessons for this chapter.

~uImportant Info~n:_________Running programs is what your computer is all
			about!  To read about running programs:

			1.  Press ~iContinue~n (key [f1]) to return to
			    the list of lessons.

			2.  Pick the first lesson, "Starting a Program."
	
~uIf You Already Know~n_____Then you can go to another chapter:
~uHow To Run Programs~n:____
			1.  Press ~iContinue~n (key [f1]).
			
			2.  Press ~iChapters~n (key [f4]) to pick another
			    chapter from the tutor.
		
th:$f1$ (Press ~iContinue~n to return to the list of lessons.) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*chap
c:n2=c
t:$h1$ Tutor Resting Place
t:$d8$
~uPlease wait~n:____________For the list of chapters...

~uYou've Just Left~n:_______Chapter 2, "$h4$ ."

~uNext on the List~n:_______Chapter 3, "Typing Your Information,"
			teaches how to use the computer keyboard for
			entering and editing text.
k:1 1 _
k:2 2 _
k:3 3 _
k:4 4 _
k:5 5 _
k:6 6 _
k:7 7 _
k:8 8 _
k:e
c:d$="Chapters/0:contents"
c:j$="begin"
c:x$="L:"!!d$!!","!!j$
xi:x$
*endall
c:j1$="endall"
t:$h1$ Tutor Exit Page
t:$d8$
~uThanks for Your Time~n!___To exit the tutor, press ~iYes,Quit~n (key [f8]).

~uTo Restart the Tutor~n:___1.  Highlight the name 'Tutor' in the PAM window.

			2.  Press ~i_Start__~n (key [f1]).

~uAfter Restarting~n:_______You can easily return to where you left off: 

			1.  When the tutor asks--"Is this your first
			    time?"--press [N] for "no."

			2.  When you see the list of chapters, highlight
			    and start this chapter:  "$h4$ ."

j(h6$<>"List of Lessons"):sless
th:$f1$ (Press ~iYes,Quit~n to leave, ~iContinue~n to select a lesson.) $h$
j:@p
*sless
t:			3.  After the chapter is loaded in memory,
			    highlight and start this lesson:
			    "$h6$

th:$f1$ (Press ~iYes,Quit~n to leave, ~iContinue~n to continue on page #p .) $h$
pr:
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 Yes,Quit___f8
k:e
as:
mj:1
c:d9=FLO(f7$)
j(p=1):ret
j(p=d9):ret
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
*ret
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:@p
m:anything
s:
j:@a
pr:
t:$h1$ Done
t:$d8$
			Good-bye from tutor... 
e:
*A
c:a9$="rpn"
c:f7$="13"
*A1
c:j0$=""
c:j1$="A1"
c:h5$=q$!!"               "
c:h6$="Starting a Program"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll be able to insert an applications
			disc and start using the programs on that disc.

			As part of this lesson, you'll be using the
			'$a9$ ' program on the utilities disc.

~uMaybe You Already Know~n:_If you think you already know how to load and
			run a program, maybe you don't need this lesson.
			
			- Press ~i_QuizMe_~n (key [f4]) for the quiz at
			  the end of this lesson.

					--OR--

			- If you want the complete lesson, press
			  ~i_ShowMe_~n (key [f3]).

th:$f1$ (Press ~i_ShowMe_~n or ~i_QuizMe_~n.)
th:______________________$f3$ #p  of $f7$ $f5$ 
q:
k:x
k:3 3 _ShowMe____f3
k:4 4 _QuizMe____f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:3
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+1
c:a9=0
c:j2$="A1A"
c:j$="J:"!!j2$
xi:j$
mj:4
k:1 1 NextPage___f1
k:2 2 PrevPage___f3
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:e
c:p=p+10
c:a9=1
c:j2$="Q1"
c:j$="J:"!!j2$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:J$
mj:7
c:j$="J:"!!j1$
j:help1
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*Q1
c:j1$="Q1"
c:j2$="Q2"
xi:x1$
t:$h8$
t:$d8$
~uTo Check Your~n___________Please answer the following questions
~uUnderstanding~n:__________(mentally):

			1.  True or false.  You can insert a new disc  
			    at ~uany~n time.

			2.  True or false.  To start a program, you need
			    to use the PAM window.

			3.  Multiple choice.  You can start a program:
			    (a) With the arrow keys and ~i_Start__~n.
			    (b) With the mouse and the display pointer.
			    (c) Both of the above.

			4.  True or false.  You can have more than one
			    program running at once.

			5.  Short answer.  How do you start a program?

th:$f1$ $k$ (Press ~iNextPage~n to check your answers.)
:___________$f3$ #p  of $f7$ $f5$
q:
c(a9=0):j0$="A5A"
c(a9=1):j0$="A1"
j:keyB
*Q2
c:j1$="Q2"
c:j0$="Q1"
c:j2$="A6"
xi:x1$
t:$h8$
t:$d8$
~uHere Are the Answers~n:___1.  False, actually.  You can insert a new
			    disc 'most any time ~uexcept~n when the red 
			    busy light is on.

		    	2.  True.  Always select PAM to start a program.

			3.  (c).  You can start programs in a variety of
			    ways.  (Try [Tab] and [Return] sometime!)

			4.  True.  You can have as many programs as
			    you'd like running at once, depending on
			    available memory.

			5.  To start a program:  Select the PAM window,
			    highlight a program name, and press ~i_Start__~n
			    (or the left mouse button).

			You should have gotten them all!

th:$f8$
q:
j:keyB
*A1A
c:j1$="A1A"
c:j0$="A1"
c:j2$="A2"
xi:x1$
t:$h8$
t:$d8$
~uOverview~n:_______________Here are some key concepts:

			- After you insert a disc in the disc drive,
			  you can ~uuse~n the programs on that disc.

			- To start a program running:
			  1.  You select the PAM window.
			  2.  You highlight the desired program name.
			  3.  You start the program with the PAM
			      ~i_Start__~n key --OR-- with the mouse.

			- You can have more than one program running at
			  a time.

			- Each program runs in its own ~uwindow~n.

			If you understand these concepts, you'll have
			no trouble starting programs.

th:$f8$
q:
j:keyB
*keyA
k:x
k:1 1 NextPage___f1
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:1
k:2 2 PrevPage___f2
k:e
c:p=p+1
c:j$="J:"!!j2$
xi:j$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:j$
mj:7
c:j$="J:"!!j1$
j:help1
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@A
*help1
c:j1$="help1"
t:$h1$ Tutor Help -- Lesson "$h6$
t:$d8$
~uHello~n!__________________You're on page 1 of a new lesson.  The lessons
			in Chapter 2, "$h4$ ," teach how to:
			- Insert a disc and start up a program from
			  that disc.
			- Change the color of individual windows.
			- Stop programs.
			- Reread the disc in the disc drive.

~uIf This Isn't Right~n_____- Choose another ~ulesson~n:
~uFor You~n:________________1.  Press ~iContinue~n (key [f1]). 
	 		2.  Press ~iLessons_~n (key [f3]) to return
			    to the list of lessons.

			- Quit the tutor altogether:
			    Press ~i__Quit__~n (key [f8]) ~utwice~n.

th:$f1$ (Press ~iContinue~n to return to page #p .) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*A2
c:j0$="A1A"
c:j1$="A2"
c:j2$="A3"
xi:x1$
t:$h8$
t:$d8$
~uIn This Lesson~n:_________The '$a9$ ' program on the utilities disc
			will serve as our example, but any program on
			any disc will do just as well.

~uLet's Go~n!_______________Follow these steps to load and run your
			program:

			1.  Press the disc drive button to remove this
			    disc from the disc drive.  (Go ahead.)

			2.  Insert the utilities disc until it clicks
			    in place.  The silver disc shutter should be
			    inserted first, with the disc label facing
			    your left.

th:$f1$ $k$ (Press ~iNextPage~n after you've inserted the new disc.)
:______$f3$ #p  of $f7$ $f5$
q:
*keyB
as:
mj:1
c:p=p+1
c:j$="J:"!!j2$
xi:j$
mj:2
c:p=p-1
c:j$="J:"!!j0$
xi:J$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:J$
mj:7
c:j$="J:"!!j1$
j:help2
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*help2
c:j1$="help2"
t:$h1$ Tutor Help -- Lesson "$h6$
t:$d8$
~uHello~n:__________________Welcome to the help for page #p .
			You're reading chapter 2: "$h4$ ."

			The point is for you to learn how to start
			and stop programs.  You can use combinations of 
			arrow keys, mouse, function keys, [Tab], and
			[Return] to put the computer to work.

			Whichever is ~ueasiest~n is the best way.

~uTo Do Something~n_________To pick a different chapter from the tutor:
~uDifferent~n:
			1.  Press ~iContinue~n (key [f1]) to get back to
			    the page you came from.

			2.  Press ~iChapters~n (key [f4]) to review the
			    list of main chapters.

th:$f1$  (Press ~iContinue~n to continue, ~i__Quit__~n to quit.) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
k:1 1 NextPage___f1
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*keyZ
k:x
k:2 2 PrevPage___f2
k:3 3 Lessons____f3
k:4 4 Chapters___f4
k:5 5 PrntPage___f5
k:7 7 __Help_____f7
k:8 8 __Quit_____f8
k:e
as:
mj:2
k:1 1 NextPage___f1
k:e
c:p=p-1
c:j$="J:"!!j0$
xi:j$
mj:3
c:j$="j:"!!l2$
xi:j$
mj:4
c:j$="j:"!!l3$
xi:j$
mj:5
q:print
c:j$="J:"!!j1$
xi:j$
mj:7
c:j$="J:"!!j1$
j:help3
mj:8
c:j$="J:"!!j1$
j:endall
m:anything
s:
j:@a
*help3
c:j1$="help3"
t:$h1$ Tutor Help -- Lesson "$h6$
t:$d8$
~uHello~n:__________________You've been reading the last page--page $f7$ --of
			this lesson.

			At this point, you can:

			- Go on to the ~unext~n lesson:
			  1.  Press ~iContinue~n (key [f1]). 
			  2.  Press ~iLessons_~n (key [f3]) to return
			      to the list of lessons.

			- Review the material in ~uthis~n lesson:
			  1.  Press ~iContinue~n (key [f1]).
			  2.  Press ~iPrevPage~n (key [f2]) to review
			      previous pages.

			- Quit the tutor altogether:
			      Press ~i__Quit__~n (key [f8]) ~utwice~n.

th:$f1$ (Press ~iContinue~n to continue, ~i__Quit__~n to quit.) $h$
q:
k:x
k:1 1 Continue___f1
k:5 5 PrntPage___f5
k:8 8 __Quit_____f8
k:e
as:
mj:1
xi:j$
mj:5
q:print
c:x$="J:"!!j1$
xi:x$
mj:8
j:endall
m:anything
s:
j:@a
*A3
c:j1$="A3"
c:j2$="A4"
c:j0$="A2"
xi:x1$
t:$h8$
t:$d8$
~uBefore Going Farther~n:___Remember how to select the PAM window?

			- From the keyboard, press [Shift][Select] --OR--

			- With a mouse, point at any part of the PAM
			  window and press the left mouse button.

~uProgram Starting~n________3.  Select the PAM window (not yet).
~uSteps~n: (cont.)
			    PAM will display an alphabetized list of the
			    programs and data on the new disc.

			4.  Select this tutor window again and read on.

			Do it!

th:$f8$
q:
j:keyB
*A4
c:j1$="A4"
c:j2$="A5"
c:j0$="A3"
xi:x1$
t:$h8$
t:$d8$
~uNow Is the Time for~n_____To start a program, you need to ~uhighlight its~n
~uHighlighting~n:___________~uname~n in the PAM window.

~uSo What's That Mean~n?____- From the keyboard, use the arrow keys to move
			  the inverse ~i_display bar_~n to the name you
			  want.
 					--OR--

			- With a mouse, point at the name you want and
			  press the left "select" button.

~uProgram Starting~n________5.  Select the PAM window (not yet).
~uSteps~n: (cont.)
			6.  Highlight the desired program name: '$a9$ '.
	
			7.  Select this tutor window again and read on.

			Do it!
th:$f8$
q:
j:keyB
*A5
c:j1$="A5"
c:j2$="A5B"
c:j0$="A4"
xi:x1$
t:$h8$
t:$d8$
~uThe Big Moment at Last~n:_Once you've highlighted the name ~i_$a9$ _~n,
			you can start the program (but not quite yet):

			- From the keyboard, press ~i_Start__~n (key [f1]
			  of PAM).
					--OR--

			- With a mouse, press the left button a second
			  and final time.

~uProgram Starting~n________8.  Select the PAM window.
~uSteps~n: (final)
			9.  Start the '$a9$ ' program.

		        10. Select this tutor window again and read on.
			    (The ~iNextPage~n key must be showing.)

			Do it!

th:$f8$
q:
j:keyB
*A5B
c:j1$="A5B"
c:j2$="A5C"
c:j0$="A5"
xi:x1$
t:$h8$
t:$d8$
~uEverything OK~n?__________If you've started the '$a9$ ' program, it's
			running in its own window, just waiting to be
			used.

~uPut in a Nutshell~n:______What you just did was to:

			1.  Insert a program disc.

			2.  Select the PAM window.

			3.  Highlight a program name.

			4.  Start the program.

~uYou've Put It To Work~n:__The assumption is that you've created a
			'$a9$ ' window on your computer.  Nice going.

th:$f8$
q:
j:keyB
*A5C
c:j1$="A5C"
c:j2$="A5D"
c:j0$="A5B"
xi:x1$
t:$h8$
t:$d8$

~uDid You Notice~n?_________When the program began, a small banner 
			appeared in the lower left of the display. The 
			banner had the name of the program.
		_____ /
		_____/
		____/	This banner indicates the program is starting, but
		___/	doesn't have anything to show you yet.  This way
		__/	you know your program is running even though it
		_/	might not display any information. 
		/
	_______/	
	______/		
	_____/		When the program is ready to show you something,
	____|		its banner disappears and its window is displayed.
	____v
~i_$a9$ _________~n


th:$f8$
q:
j:keyB
*A5D
c:j1$="A5D"
c:j2$="A5A"
c:j0$="A5C"
xi:x1$
t:$h8$
t:$d8$
~uWhen the Program Stops...~n_______Its window usually goes away.  However,
				some windows remain even though the program
				has stopped. 

~uHow Do You Know When a~n__________Either its window disappears or the name
  ~uProgram Has Stopped~n?__________in the window's banner becomes enclosed
				in parentheses.

		+---------------+
		|~i__(core~_wars)__~n|
		+---------------+---------------------------------------+
		| Bytes bombed: 12438					|
		| end of program					|
		|							|
		+-------------------------------------------------------+

th:$f8$
q:
j:keyB
*A5A
c:j1$="A5A"
c:j0$="A5D"
c:j2$="Q1"
xi:x1$
t:$h8$
t:$d8$
~uNow Is Not the Time~n:____How you ~ustart~n the '$a9$ ' program is one
			thing.  How you ~uuse~n the program is another
			--refer to ~uUsing Your Integral PC~n for details.

~uI Will Tell You This~n:__Here's how to ~ustop~n the '$a9$ ' program:

			1.  Select the '$a9$ ' window so that its menu
			    is clearly ~uvisible~n (not yet).

			2.  Press ~i__exit__~n (key [f8]).

			    You'll exit the '$a9$ ' program and 
			    eliminate its window.

			3.  Reinsert the ~ututor disc~n and make sure
			    the tutor window is ~uin front~n.
			
			Do it!

th:$f1$ $k$ (Press ~iNextPage~n after reinserting the tutor disc.)
:_______$f3$ #p  of $f7$ $f5$
q:
j:keyB
*A6
c:j1$="A6"
c:j2$=""
c:j0$="Q2"
xi:x1$
t:$h8$
t:$d8$
~uIn Short~n:_______________What you see listed as a program in the
			PAM window is what you can start.
			
			Putting the computer to work is a matter of
			(1) highlighting and (2) starting programs.

~uThat's It~n!______________That's all you need to know in order to use
			this computer--insert the disc you want,
			highlight the desired program name, and start
			the program.

~uOf Course There's More~n:_You can read more about the computer from
			this tutor disc or from the manuals.  You're
			welcome to learn as you have time.

			On this disc, there are lessons that cover every-
			thing from ~uprinting files~n to ~umoving windows~n.
			From here, the choice is yours.

th:$g6$ #p  of $f7$ $f5$
q:
j:keyZ
*D
c:f7$="7"
*D1
c:j0$=""
c:j1$="D1"
c:j2$="D2"
c:h5$=q$!!"          "
c:h6$="Inverting Window Colors"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll know how to change the color of
			a window:

			+----------------------------------------------+
			|______________________________________________|
			|___From black characters______________________|
			|_______on an amber background...______________|
			|______________________________________________|
			+----------------------------------------------+

			+----------------------------------------------+
			|~i______________________________________________~n|
			|~i___...to amber characters_____________________~n|
			|~i_______on a black background._________________~n|
			|~i______________________________________________~n|
			+----------------------------------------------+

th:$f8$
q:
j:keyA
*D2
c:j0$="D1"
c:j1$="D2"
c:j2$="D3"
xi:x1$
t:$h8$
t:$d8$
~uKey Concept~n:____________The windows on the display initially have
			amber backgrounds.  You can change windows
			individually to ~i black ~n backgrounds.

			To change the color of the tutor window:

			1.  Press the [User/System] key at the top
			    center of the keyboard (go ahead).

			2.  Press ~i_Invert_~n (key [f3]).  Things change!

			3.  Press the [User/System] key again.

			Note:  You ~umust~n press the [User/System] key
			a total of ~utwo~n times to switch between the
			~uSystem menu~n and the ~uUser menu~n.

th:$f1$ $k$ (Press ~iNextPage~n after inverting window color.)
:___________$f3$ #p  of $f7$ $f5$
q:
j:keyB
*D3
c:j0$="D2"
c:j1$="D3"
c:j2$="D3A"
xi:x1$
t:$h8$
t:$d8$
~uDo You Like A~n___________If you like the way the tutor window looks in
~uBlack Background~n?_______inverse, fine--leave it this way.

~uTry This~n:_______________Press [User/System] twice more.

			Note that the ~i_Invert_~n label has changed to:
			
			    ~i_Invert*~n (with an asterisk)
			
			--when the window has a black background.

			If you want to ~ure~ninvert the color, press
			~iPrevPage~n (key [f2]), and repeat steps 1 through 3.

~uInverting PAM~n:__________For your information, if you invert the color
			of the ~uPAM~n window, then every time you highlight
			and start a new program, the new program will
			"inherit" a black window, the same as PAM.

th:$f8$
q:
j:keyB
*D3A
c:j1$="D3A"
c:j0$="D3"
c:j2$="D4"
xi:x1$
t:$h8$
t:$d8$
~uA Discovery~n:____________Pressing [User/System] has revealed a ~unew menu~n
			for function keys [f1]-[f8].

			The computer lets you switch between these two sets
			of keys for ~ueach~n window in the display.  You'll
			use this second set in Chapter 7 to control other
			window operations, such as moving and resizing
			windows.

~uBy the Way~n:_____________The [Menu] key--next to the [User/System] key
			--turns the menu off and on.

			1.  Press [Menu] once to turn off the menu.

			2.  Press [Menu] a second time to turn the menu
			    back on.

			Try it!  

th:$f8$
q:
j:keyB
*D4
c:d9=flo(f7$)
c:p=d9-2
c:j0$="D3A"
c:j1$="D4"
c(m=1):j2$="D4A"
c(m=0):j2$="D5"
xi:x1$
t:$h8$
t:$d8$
~uA Menu Tip~n:_____________Look at the bottom of the display in the center.
			You'll see:

			   ~i_Tutor__~n    <-- This shows that the ~uUser~n
			    ~i_User_~n         ~umenu~n is active.

			Now press [User/System] once.  You'll see:

			   ~i_Tutor_~n     <-- This shows that the ~uSystem~n
			  ~i_System__~n        ~umenu~n is active.

~uAlways, Always~n:_________When you want to read the tutor window (most
			of the time), make sure that the User menu is
			showing--~unot~n the System menu!

~uIn Fact~n:________________Press [User/System] now to access the User menu.

th:$f1$ $k$ (Press ~iNextPage~n in the User menu.)
:__________________________$f3$ #p  of $f7$ $f5$
q:
j:keyB
*D4A
c:j1$="D4A"
c:j0$="D4"
c:j2$="D5"
xi:x1$
t:$h8$
t:$d8$
~uFor Mouse Users~n:________You can "press" the [User/System] key with the mouse:

			1.  Point the display arrow at the center of the
			    menu between key labels [f4] and [f5] (go ahead).  
			
			2.  Switch to the System menu--press the left
			    mouse button while at the center of the menu.

			3.  Switch back to the tutor menu--press it again.
			
~uAgain--Mouse Users~n:_____The ~uright~n button on the mouse works
			~uexactly~n the way the [Menu] key does.

			1.  Press the right button once to turn off the
			    menu (go ahead).

			2.  Press the right button a second time to turn
			    on the menu.

th:$f8$
q:
j:keyB
*D5
c(m=1):j0$="D4A"
c(m=0):j0$="D4"
c:j1$="D5"
c:j2$=""
xi:x1$
t:$h8$
t:$d8$
~uMost of the Time~n:_______You'll want to leave the menu turned ~uon~n,
			since so many programs use the function keys.

~uSummary~n:________________- Press [User/System], ~i_Invert_~n, and
			  [User/System] to change the color of the
			  active window.

			- Press [Menu] to turn the menu at the bottom
			  of the display off and on.

			- You can "mouse" the [User/System] and [Menu]
			  keys as well as press them from the keyboard.

~uNext~n:___________________The next lesson, "Stopping a Program," shows:

			- How to stop programs once you've started them.

			- How to eliminate program windows.

th:$g6$ $f7$  of $f7$ $f5$
q:
j:keyZ
*B
c:f7$="6"
*B1
c:j0$=""
c:a9$="rpn"
c:j1$="B1"
c:j2$="B2"
c:h5$=q$!!"              "
c:h6$="Stopping a Program"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll know how to stop a program--both gently
			and forcibly.

~uBegin~n:__________________You already know that you can run more than one
			program at a time on the $n8$ .

			You also know that each program runs in its own
			window.

~uIn General~n:_____________When you ~ustop~n a program, you also ~ueliminate~n
			its window.
			
			Note that stopping a program affects only the
			program in the ~uactive window~n (usually the one
			in front).

th:$f8$
q:
j:keyA
*B2
c:j1$="B2"
c:j2$="B2A"
c:j0$="B1"
xi:x1$
t:$h8$
t:$d8$
~uReference Information~n:__Please just read--don't try these right now.

			Here are three possible ways to stop a program 
			and eliminate the program window:

			- Press function key [f8].  Most programs 
			  have a ~i__Quit__~n or an ~i__Exit__~n key of
			  some sort at that location.

			- Press [Stop].  The [Stop] key (at the upper
			  left corner of the keyboard) is usually
			  forceful enough to stop a program--or at least
			  interrupt it.

			- Press [Shift][Stop].  This keystroke will
			  eliminate a program window, no matter what.


th:$f8$
q:
j:keyB
*B2A
c:j1$="B2A"
c:j0$="B2"
c:j2$="B2AA"
xi:x1$
t:$h8$
t:$d8$
~uThe Best Way~n:___________The best way to stop a program is to leave it
			"gently"--by pressing function key [f8].  Most
			programs will make sure you've had a chance to
			save your work on disc before leaving.

~uThe Next Best~n___________The [Stop] key is for programs that don't
~uWay~n:____________________have a ~i__Quit__~n or ~i__Exit__~n option.  Use
			[Stop] only when you have to.

~uAnd Reader, Beware~n!_____If you press [Shift][Stop], you're taking
			~userious~n action.  You're forcibly stopping
			the program.

			Using [Shift][Stop] is like saying, "I don't
			care what you're doing or what changes you've
			made to my files--I want out!"
th:$f8$
q:
j:keyB
*B2AA
c:j1$="B2AA"
c:j0$="B2A"
c:j2$="B2B"
xi:x1$
t:$h8$
t:$d8$
~uThere's Even a More~n_____The last lesson of Chapter 1, "Starting Over,"
~uBrutal Way~n:_____________shows the use of the [Shift][Reset] keystroke.

			When you resort to pressing [Shift][Reset], all
			hope is lost for any programs in progress!

                                      ~_~_~_~_~_~_~_~_
                                     /        \
                                    /   REST   \
                                   /     IN     \
                                  /    PEACE     \
                                 |                |
                                 |    Programs    |
                                 |   killed by a  |
                                 |      Reset     |
                                 |                |
                                *|     *  *  *    | *
                       ~_~_~_~_~_~_~_)/\\~_//(\/(/\)/\//\/|~_)~_~_~_~_~_~_

th:$f8$
q:
j:keyB
*B2B
c:j1$="B2B"
c:j0$="B2AA"
c:j2$="B3"
xi:x1$
t:$h8$
t:$d8$
~uIf You'd Like To~n________Use the 'status' program from the Utilities Disc.
~uPractice Stopping~n:______(Hint:  Press ~iPrntPage~n--key [f5]--to save
			these instructions before continuing.)

			1.  Insert the Utilities disc (go ahead).

			2.  Select the PAM window, then highlight and start
			    the program named 'status'.

			3.  Since 'status' doesn't offer a ~i__Quit__~n key,
			    verify that pressing [f8] has no effect.
			    
			4.  Verify that [Stop] and [Shift][Stop] both 
			    eliminate the program window, restarting the
			    program each time.  (Before pressing [Shift]
			    [Stop], make sure that the 'status' window is
			    in front!)

th:$f1$ $k$ (After step 4, insert the tutor disc and press ~iNextPage~n.)
:__$f3$ #p  of $f7$ $f5$
q:
j:keyB
*B3
c:j1$="B3"
c:j2$=""
c:j0$="B2B"
xi:x1$
t:$h8$
t:$d8$
~uBy the Way~n:_____________If you press the tutor ~i__Quit__~n key, the
			tutor will ask you to press [f8] a ~usecond~n time
			--just to confirm that you really want out.  The
			tutor will ~uignore~n [Stop] but ~unot~n [Shift][Stop]. 

~uSummary~n:________________- When you stop a program, you usually eliminate
			  its window.

			- You stop one program at a time--the program in
			  the active window.

			- Use ~i__Quit__~n (key [f8]) when you can, [Stop]
			  otherwise, and [Shift][Stop] only when you 
			  have to.

~uNext~n:___________________The next lesson, "Updating PAM," shows how to
			cause PAM to reread the disc--to make sure that
			the PAM window stays current.

th:$g6$ #p  of $f7$ $f5$
q:
j:keyZ
*E
c:f7$="7"
*E1
c:j0$=""
c:j1$="E1"
c:j2$="E2"
c:h5$=q$!!"                    "
c:h6$="Updating PAM"!!q$
c:h8$=h1$!!h2$!!h4$!!h5$!!h3$!!h6$
c:p=1
c:f9$=f4$!!f7$!!f5$
xi:x1$
t:$h8$
t:$d8$
~uAfter This Lesson~n:______You'll be able to cause PAM to reread the disc
			and update the PAM window.

~uPrerequisites~n:__________You need to know:

			- How to switch back and forth between this
		 	  tutor window and the PAM window.

			- How to highlight a name in the PAM window (with
			  the arrow keys or the mouse).

~uHow PAM Works~n:__________At all times, you can see the names of your
			program and data files in the PAM window.
			
			PAM automatically changes the list of files as
			~uthey~n change.  For example, when you rename
			or delete a file, PAM updates the PAM window.

th:$f8$
q:
j:keyA
*E2
c:j1$="E2"
c:j2$="E3"
c:j0$="E1"
xi:x1$
t:$h8$
t:$d8$
~uWhen Do YOU Need~n________Sometimes when you ~ucreate~n a new file, PAM
~uTo Update PAM~n?__________doesn't get the news.  At those times, you can
			tell PAM yourself that a change has occurred.

			To update the PAM window an easy way:

			1.  Remove the disc from the built-in disc drive
			    (not yet).

			2.  Insert the disc until it clicks back in place.

			3.  Select the PAM window.  PAM will update the
			    window to show the files on the newly
			    inserted disc.
			
			On the next page, you'll try this way using the
			tutor disc.

th:$f8$
q:
j:keyB
*E3
c:j1$="E3"
c:j2$="E4"
c:j0$="E2"
xi:x1$
t:$h8$
t:$d8$
~uLet's Go~n!_______________1.  Press the disc drive button to remove
			    the tutor disc.  (Go ahead.)

		    	2.  Reinsert the tutor disc.  Note that the red
			    busy light turns on--the system is checking
			    to see what's happened.

			3.  Select the PAM window.  Note that it's
			    cleared and updated to show that the
			    ~uOpen Folder~n is '/MyBook'.  (Go ahead.)

			4.  Select this tutor window again and read on.

~uThe Conclusion~n?_________When you're using just the built-in  disc drive
			and you insert a disc, PAM will update the PAM
			window to show what's on the disc.

th:$f8$
q:
j:keyB
*E4
c:j1$="E4"
c:j2$="E5"
c:j0$="E3"
xi:x1$
t:$h8$
t:$d8$
~uTry It Again~n:___________This time, ~uremove~n and ~ureinsert~n the tutor
			disc while the PAM window is ~uin front~n.

			Do it!

~uDid You See This~n?_______- The PAM display cleared --AND--
			  The ~uOpen Folder~n changed to a slash ('/').

			- When you reinserted the tutor disc, PAM
			  promptly updated the PAM window.

~uBy the Way~n:_____________The term ~uopen folder~n means a place where
			your files are kept.  All the tutor files are
			contained in the 'MyBook' folder--really just a 
			name for the tutor disc.

			When no disc is in the drive, the open folder 
			changes to a slash ('/').

th:$f8$
q:
j:keyB
*E5
c:j1$="E5"
c:j2$="E6"
c:j0$="E4"
xi:x1$
t:$h8$
t:$d8$
~uRead Before Doing~n:______To update the PAM window a more sophisticated
			way:

			1.  Select the PAM window (not yet).

			2.  Highlight the name of the open folder, thus:

			    ~uOpen Folder~n:_~i_/MyBook_~n

			    (Note that key label [f1] of PAM changes to
			    ~i_Reread_~n.)

			3.  Press ~i_Reread_~n (key [f1]).  The PAM window
			    will be cleared, the disc will be reread, and
			    the list of files will be updated.

			Do it!

th:$f1$ $k$ (Press ~iNextPage~n after trying steps 1 through 3.)
:___________$f3$ #p  of $f7$ $f5$
q:
j:keyB
*E6
c:j1$="E6"
c:j2$="E7"
c:j0$="E5"
xi:x1$
t:$h8$
t:$d8$
~uHow Often Do You Need~n___Normally, you ~uwon't~n need to update the display.
~uTo Do This~n?_____________PAM is pretty good at keeping things current.

			Use the ~i_Reread_~n key only after creating a
			file with an applications program, such as a word
			processor or spreadsheet program.

~uSummary~n:________________- PAM tries to maintain an updated list of the
			  files on your disc.

			- After you've removed a disc, the file list
			  will be updated--as soon as the PAM window
			  is made active.
			  
		  	- You can update the PAM window manually:
			  1.  Select the PAM window.
			  2.  Highlight the name of the open folder.
			  3.  Press ~i_Reread_~n (key [f1]).
th:$f8$
q:
j:keyB
*E7
c:j1$="E7"
c:j2$=""
c:j0$="E6"
xi:x1$
t:$h8$
t:$d8$
~uDone~n:___________________You should feel good--you've made it through
			some pretty heavy material in this chapter.

			    Maybe you'd like a break?

~uNext~n:___________________At any rate, the next chapter, "Typing Your
			Information,"  shows how to use the typing and
			editing keys of the computer.

th:$f1$ $k$ (Press ~iChapters~n to pick from the list of chapters.)
:_______$f3$ #p  of $f7$ $f5$
q:
j:keyZ
*SYSX
th:$h1$
t:
:Welcome to PILOT!  Type a command and press [Return]:
c:z8=1
J:BEGIN9
*SYYY
TH:calc mode ([Return] to exit):_
AX:$Z9$
J(Z9$=""):BEGIN9
M:=
CN:Z9$="Z9="!!Z9$
C:Z9$="C:"!!Z9$
XI:Z9$
TE:..no good
JE:@A
TN:Answer is #Z9 .
J:SYYY
*BEGIN9
TH:#z8 )_
AX: $Z9$
c(z9$<>""):z8=z8+1
M:bye
JY: calret
M:calc
JY: SYYY
XI: Z9$
TE: ...oh, well
J:BEGIN9
*calret
c:x$="e:"!!j1$
xi:x$